Benoit Freslon's blog - Game Design, Flash games, ActionScript tutorials ... » ActionScript3 as3

ActionScript: Protect your Flash games on the web, sitelock all your games.

admin — Fri, 13 Jan 2012 15:29:33 +0000

If you want to submit your games on one game portals DO NOT UPLOAD YOUR GAMES WITHOUT A SITELOCK SCRIPT.

WHY ?

Your games can be “stolen” by game portals. Or if you didn’t finish your game it’s a really a “pain in the ass” to update your games spread on all the web.

I tried lot of code for sitelocking my games but some of them are in ActionScript 2.0 or totally out of date. Some of them can’t work with the “https” or without the “www” characters.
Another example when you to want to test your game on your local computer you have to comment the script. And you can forget to uncomment the sitelock script when you submit your game on the web.

So I decided to create my own script.

This is a short version of my script.
But this one is perfect for all uses.

Installation

Copy and Paste this code and add your domains into the array “[ ]” separated by commas :

["kongregate.com", ..., ...]

You can lock the local mode by adding a second parameter : false
The default value is set to true.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

sitelock(["kongregate.com","benoitfreslon.com"])

/**
* Sitelock your swf file on domains
*
* @param arrDomain List of all authorized domains
* @param local This swf can be played on local computer ?
*/
function sitelock(arrDomain:Array, local:Boolean = true):void {

var isAut:Boolean = false;

var url:String = root.loaderInfo.url;
var arr:Array = root.loaderInfo.url.split("://");

var domain:String = arr[1].split("/")[0];

// localmode
if (url.split("file://").length > 1) {
if (local) {
//trace("Local mode is autorized");
return
} else {
destroy();
return;
}
}
for (var i:String in arrDomain) {
arr = domain.split(arrDomain[i]);
if (arr.length > 1) {
isAut = true;
domain = arrDomain[i];
//trace("*** Sitelock: Domain found");
break;
}

}
if (! isAut) {
//trace("*** Sitelock: Not authentified");
destroy();
}
return;
}
/**
* This function is called when the game is locked.
*/
function destroy() {
// Domain error
trace("*** Domain Error ***");
root.alpha = 0
}

ActionScript: Good practices in Flash developement

admin — Tue, 15 Nov 2011 11:19:17 +0000

Here some tips and a list of good practices in Flash developement.
These tips are usefull for coders and designers.

Prepare your layers

When you create a new .fla file prepare your layers like this :

Add a new layers “Actions” on the top of the list. This layer will be dedicated to ActionScript.
Then lock this layer to avoid adding graphic elements here.

Lock the main script

In order to keep in sight your main script, I recommend to lock this script by clicking on the pin on the bottom of the Actions pannel like this :

Permit debugging

Enabled the Flash debugger to display more efficient error messages.

File> Publish settings… > Permit debugging

You can find this kind of message if you got an execution error : (My Flash player is in french language)

1 2	TypeError: Error #1009: Il est impossible d'accéder à la propriété ou à la méthode d'une référence d'objet nul. at Untitled_fla::MainTimeline/frame1()[Untitled_fla.MainTimeline::frame1:3]

This error is located on the 1st frame on line 3. So useful !

However you must uncheck this option before publishing your swf on the web.

The library

Order you symbols and your medias in folders. Name your folders with explicit names.

Name your folders by using the prefix “_”.
This tip can keep all your folders in the top of the list.
And you can name a symbol or a media like your foler.

Example: _Ball Folder own the Ball symbol.

The library orders elements and folders by alphabetical order.
Your library is now more lisible.

Name your symbols and your medias correctly

When you name your symbols or you media, particularly MovieClips, Istrongly recommand using a capital letter on the first character.

Why ?

When flash adds a new MovieClip with ActionScript he uses the class name exported for ActionScript.
By convention a class name has always a capital letter on the first character.

var mc = new BlueScreenOfTheDeath();
addChild(mc)

However the symbol name match with the class name when you link the symbol for ActionScript. So keep the same name.

Naming convention

ActionScript looks like Java so use the Java naming convention.

http://en.wikipedia.org/wiki/Naming_convention_(programming)#Language-specific_conventions

ActionScript: Tutorial How to create a gravity like a Mario platformer

admin — Wed, 02 Feb 2011 14:21:47 +0000

In this little tutorial you will learn how to create a gravity like a Mario platformer.

Let’s start!

Get files

Save these 2 sprites (Right click > Save as)

Open Flash and create a new ActionScript 3.0 document.
Document properties: 24 fps, 550×400 by default.

Create the Hero MovieClip

Create a new Symbol: Insert > New symbol > MovieClip
Symbol name: Hero
Check Export for ActionScript
And Click OK

Now you are in you Hero symbol! Perfect!
Import the first sprite: mario_stand.png on the first frame:
File > Import > Import to stage > mario_stand.png
Set the sprite just on the top of the little black cross (pivot point)
Now create an empty keyframe on the timeline:
Timeline > 2nd frame on the timeline > Right Click > Create empty Keyframe
Import the second sprite: mario_jump.jpg on the second keyframe
Then create a new layer on the top and set 2 labels names
Insert > Timeline > New layer
And add 2 labels names:
On the timeline click on the first key frame with the mario_stand.png sprite and go to the Properties pannel > Label > Name > stand
On the timeline click on the second key frame with the mario_jump.png sprite and go to the Properties pannel > Label > Name > jump

Add the jump script

Back to the main scene: Click on the Scene 1
Add a new layer named “Actions”: Insert > Timeline > New layer
And open the Actions pannel: Timeline > Actions Layer > Keyframe > Right click > Actions
Finally copy and paste this code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

// The game gravity
var gravity = 0.8;

// The floor position (y)
var floor = 300;

// Add the hero MovieClip
var hero = new Hero();
// Set the x position
hero.x = 550/2;
// Set the y position on the floor
hero.y = floor;
// Set the hero state to "stand"
hero.gotoAndStop("stand");

// Add hero on the display list
addChild(hero);

// Create and set the speedY property to 0
hero.speedY = 0
// Create and set the jump impulsion to 10
hero.impulsion = 10;
// Add an enter frame event
hero.addEventListener(Event.ENTER_FRAME, heroEnterFrame)
function heroEnterFrame (pEvent)
{
// On each frames...

// Set the world gravity
hero.speedY += gravity;

// Move the hero with his speedY
hero.y += hero.speedY;

// If the y property is larger than the floor position
if (hero.y > floor)
{
// Set the hero on the floor
hero.y = floor
// Cancel the current speed
hero.speedY = 0;
// Change the state to stand
hero.gotoAndStop("stand");
}
}

// Add a mouse event on the stage
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown)

function mouseDown (pEvent)
{
// When the user click on the stage...

// If the hero is standing
if (hero.currentLabel == "stand")
{
// Set the new speedY with the hero impulsion
hero.speedY = -hero.impulsion;
// And change the state to jump
hero.gotoAndStop("jump");
}
}

Download sources: www.benoitfreslon.com_Create_gravity_like_a_mario_plateformer

ActionScript: Move an object with keyboard with absolute controls

admin — Tue, 01 Feb 2011 11:29:30 +0000

In this tip I will show you how to move an object with keyboard with absolute controls.

What is the absolute controls?

The direction of your object will be calculated depending the object orientation. (Biohazard, Micro Machines, Gears of War). This code is very usefull if you design a car game.

How to make an absolute control in Flash?

Get the arrow key status (key is up/key is down);
Move or rotate the object on enter frame with the new velocity (Left and Right keys: rotate, Up key: forward, Down key: backward);

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90

// Assign 4 booleans for the 4 arrow keys
var keyUp = false;
var keyDown = false;
var keyLeft = false;
var keyRight = false;

// Add the keyboard event (KEY_DOWN) on the stage
stage.addEventListener(KeyboardEvent.KEY_DOWN, pressKey);
function pressKey(pEvent)
{
// If an arrow key is down, switch the value to true to the assigned variable
if (pEvent.keyCode == 38)
{
keyUp = true;
}
else if (pEvent.keyCode == 40)
{
keyDown = true;
}
else if (pEvent.keyCode == 37)
{
keyLeft = true;
}
else if (pEvent.keyCode == 39)
{
keyRight = true;
}
}
// Add the keyboard event (KEY_UP) on the stage
stage.addEventListener(KeyboardEvent.KEY_UP, releaseKey);
function releaseKey(pEvent)
{
// If the arrow key is up, switch the value to false to the assigned variable
if (pEvent.keyCode == 38)
{
keyUp = false;
}
else if (pEvent.keyCode == 40)
{
keyDown = false;
}
else if (pEvent.keyCode == 37)
{
keyLeft = false;
}
else if (pEvent.keyCode == 39)
{
keyRight = false;
}
}

// Set the velocity of the object
var speed = 6;
// And the rotation speed
var rotationSpeed = 5;

// Add an enter frame event on the moving object
myCircle.addEventListener(Event.ENTER_FRAME, circleEnterFrame);
function circleEnterFrame(pEvent)
{
// Set the default velocity to 0 if no key is pressed
var velocity = 0;
if (keyUp)
{
// If the key up is pressed set the new velocity to the speed value
velocity = speed;
}
if (keyDown)
{
// If the key down is pressed set the new velocity to the half speed value
velocity = -speed/2;
}
if (keyLeft)
{
// rotate the object
pEvent.currentTarget.rotation -= rotationSpeed;
}
if (keyRight)
{
// rotate the object
pEvent.currentTarget.rotation += rotationSpeed;
}

// Convert the degreeAngle to the radian angle
var angleRadian = pEvent.currentTarget.rotation / 180 * Math.PI;

// Move the object with the radian angle and the object speed
pEvent.currentTarget.x += Math.cos(angleRadian) * velocity;
pEvent.currentTarget.y += Math.sin(angleRadian) * velocity;
}

Download source: www.benoitfreslon.com_Move_an_object_with_keyboard_with_absolute_controls

ActionScript: Move an object with keyboard with camera relative control

admin — Tue, 04 Jan 2011 16:22:25 +0000

In this tip I will show you how to move an object with keyboard with camera relative control.

What is a camera relative control?

The direction of your object will be calculated depending the camera position. (Mario 64, Uncharted, GTA 3, etc.).
Eg: If press the right button the character will go on the right.

How to make a camera relative control?

Get the arrow key status (key is up/key is down)
Set the direction vector
Move the object on enter frame with the direction vector

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

// Assign 4 booleans for the 4 arrow keys
var keyUp = false;
var keyDown = false;
var keyLeft = false;
var keyRight = false;

// Add the keyboard event (KEY_DOWN) on the stage
stage.addEventListener(KeyboardEvent.KEY_DOWN, pressKey);
function pressKey(pEvent) {
// If an arrow key is down, switch the value to true to the assigned variable
if (pEvent.keyCode == 38) {
keyUp = true;
} else if (pEvent.keyCode == 40) {
keyDown = true;
} else if (pEvent.keyCode == 37) {
keyLeft = true;
} else if (pEvent.keyCode == 39) {
keyRight = true;
}
}
// Add the keyboard event (KEY_UP) on the stage
stage.addEventListener(KeyboardEvent.KEY_UP, releaseKey);
function releaseKey(pEvent) {
// If the arrow key is up, switch the value to false to the assigned variable
if (pEvent.keyCode == 38) {
keyUp = false;
} else if (pEvent.keyCode == 40) {
keyDown = false;
} else if (pEvent.keyCode == 37) {
keyLeft = false;
} else if (pEvent.keyCode == 39) {
keyRight = false;
}
}

// Set the velocity of the object
var speed = 6;

// Add an enter frame event on the moving object
myCircle.addEventListener(Event.ENTER_FRAME, circleEnterFrame);
function circleEnterFrame(pEvent) {
// Create a 2D vector in order to get the object direction according the arrow keys
var vector = new Point(0,0);
if (keyUp) {
// If keyUp is true add the -1 value on the y axis
vector.y += -1;
}
if (keyDown) {
// If keyDown is true add the 1 value on the y axis
vector.y += 1;
}
if (keyLeft) {
// If keyLeft is true add the -1 value on the x axis
vector.x += -1;
}
if (keyRight) {
// If keyRight is true add the 1 value on the x axis
vector.x += 1;
}

// Get the radian angle of the direction
var angle = Math.atan2(vector.y,vector.x);

// If vector lenght is not null
if (vector.length > 0) {
// Move the object with the angle and the object speed
pEvent.currentTarget.x += Math.cos(angle) * speed;
pEvent.currentTarget.y += Math.sin(angle) * speed;
}
}

[kml_flashembed publishmethod="static" fversion="10.0.0" movie="http://www.benoitfreslon.com/wp-content/uploads/2011/01/www.benoitfreslon.com-Move-an-objet-with-keyboard-with-camera-relative-control.swf" width="550" height="400" targetclass="flashmovie"]

Donwload source: www.benoitfreslon.com-Move-an-objet-with-keyboard-with-camera-relative-control.zip

ActionScript: Move an object to coordinates with smoothing

admin — Mon, 03 Jan 2011 15:53:50 +0000

There is a simple formula to move an object to coordinates with smoothing.
The speed will decrease with smooth during the time.

speed = distance_between_objects / smoothing

The distance will decrease because the distance will decrease too.

If I set values I got:

object.x = 50
targetX = 100

speedX = (targetX – object.x) / 5

On the first frame: speed = 10
object.x += (100 – 50) /5 > 50/5 > 10
> object.x = 50+10 = 60

On the second frame: speed = 8
object.x += (100 – 60) /5 > 40/5 = 8
> object.x = 60 + 8 = 68

On the third frame: speed = 6,4
object.x += (100 – 68) / 5 > 32/5 = 6,4
> object.x = 68 + 6,4 = 74,4

etc.

On the 100th frame: speed = 0
object.x += (100 – 100) / 5 > 0 /5 = 0
> object.x = 100 + 0 = 100

Source:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

// Add a mouse event on the stage
stage.addEventListener(MouseEvent.CLICK, click);
function click(pEvent) {
// On click set the new x and y coordinates
myBall.targetX = stage.mouseX;
myBall.targetY = stage.mouseY;
}

// Set default coordinates
myBall.targetX = 200;
myBall.targetY = 200;

// Add an enter frame event on the ball
myBall.addEventListener(Event.ENTER_FRAME, ballEnterFrame);
function ballEnterFrame(pEvent) {
// On enter frame move the ball to the target coordinates
var b = pEvent.currentTarget;
b.x += (b.targetX - b.x) / 8;
b.y += (b.targetY - b.y) / 8;
}

Exemple:

Download source: www.benoitfreslon.com Move an object to coordinates with smoothing.zip

ActionScript: Launch a function after a delay with setTimeout

admin — Mon, 03 Jan 2011 14:35:38 +0000

There are different ways to launch a function after a delay:

With the enter frame event;
With the Timer class;
With a motion tween;
With the enter frame event and the getTimer() method;
And with the setTimeout function (See setTimeout help on Adobe);

How to master the setTimeout ?

First of all you must create a variable assigned to the setTimeout identifier;

1	var intervalIndentifier

The setTimeout function returns an identifier (uint) when you call this function. Save this identifier into the assigned variable;

1
2
3
4
5

// The hello function will be launched in 2000 ms
intervalIdentifier = setTimeout(hello, 2000)
function hello() {
trace("function launched")
}

This identifier must be clear with the clearTimeout function in order to stop the setTimeout;

1	clearTimeout(intervalIdentifier)

NB:

If you want to launch a setInterval already launched don’t forget to clear the previous setInterval. In witch case the previous setInterval won’t be stopped;
The setTimeout function can’t be paused or resumed;
Assign one variable by one setTimout;
The setTimeout function is based on clock time not on frames time;
When you clear the setTimeout the closure function is not launched;
You don’t have to clear the setTimeout when the setTimeout is already finished;

Add parameters

The setTimeout function can receive one or several arguments. Those arguments are passed to the closure function.
To add arguments just add your arguments after the second parameter into the setTimeout function:
Obviously your closure function must have the same number of arguments.

1
2
3
4

intervalIdentifier = setTimeout(hello, 2000, "world", "www.benoitfreslon.com")
function hello(arg1, arg2) {
trace(arg1, arg2)
}

Exemple:

Download source: www.benoitfreslon.com Launch a function after a delay with setTimeout.zip

ActionScript: Throw bullets to mouse direction

admin — Mon, 27 Dec 2010 12:50:13 +0000

After calculating the angle of 2 graphic objects, you can also use this angle to throw a bullet to the object direction with the trigonometry.

How ?

Calculating the angle (in radian) between 2 graphics objects with the Math.atan2 method (cf. Orient object to the mouse cursor).
On click, display a bullet to the “tank” position and add an “enter frame” event on this bullet.
And save the angle between the tank and the mouse cursor on the new bullet.
Use this angle on the “enter frame” event to calculate the x and y speed with the cosinus and the sinus.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

import flash.display.MovieClip;
import flash.geom.Point;
import flash.events.MouseEvent;

// Code by Benoit Freslon.
// Tutorials, Flash games:
// http://www.benoitfreslon.com

// This object will always look at the mouse cursor
myTank.addEventListener(Event.ENTER_FRAME, tankEnterFrame);
// This function will be launched every frame (25 times by seconds);
function tankEnterFrame(pEvt) {
// pEvt.currentTarget: myTank
var mc = pEvt.currentTarget;
// Get the radian angle between the tank and the cursor
// You can also replace mouseX and mouseY by another coordinates
var angleRadian = Math.atan2(mouseY - mc.y,mouseX - mc.x);
// Convert the radian angle in dedree angle
var angleDegree = angleRadian * 180 / Math.PI;
// Set the orientation
mc.rotation = angleDegree;
// Display angle of rotation in degree
txtAngle.text = Math.round(angleDegree) + "°";
}

// Add a mouse down event on stage
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);

function mouseDown(pEvent) {
// Create a new bullet
var b = new Bullet();
// Set his position to the tank position
b.x = myTank.x;
b.y = myTank.y;
// Save the randian angle between the mouse and the tank
// This angle will set the direction of the bullet
b.angleRadian = Math.atan2(mouseY - myTank.y,mouseX -myTank.x);
// Add an enter frame event on each bullet
b.addEventListener(Event.ENTER_FRAME, bulletEnterFrame);
// Add this display object on the display list
addChild(b);
}

// Velocity of each bullet
var speed = 8;

function bulletEnterFrame(pEvent) {
// Get the current object (Bullet)
var b = pEvent.currentTarget;
// Move this bullet on each frames
// On X axis use the cosinus angle
b.x += Math.cos(b.angleRadian) * speed;
// On Y axis use the sinus angle
b.y += Math.sin(b.angleRadian) * speed;
// Orient the bullet to the direction
b.rotation = b.angleRadian * 180 / Math.PI;
// You have to remove each created bullet
// So after every moves you must check bullet position
// If the bullet is out of the screen
if (b.x < 0 || b.x > 400 || b.y < 0 || b.y > 400) {
// Remove it from the display list
removeChild(b);
// /!\ AND REOMOVE HIS EVENT LISTER
b.removeEventListener(Event.ENTER_FRAME, bulletEnterFrame);
}
}

Download source: www.benoitfreslon.com_Throw_bullets_to_mouse_direction.zip

ActionScript: Detect collision between 2 circles

admin — Fri, 03 Dec 2010 11:02:25 +0000

With the Pythagoeran theorem you can detect collision with 2 circles.

You just have to get the rays of 2 circles with the width property divided by 2.
Actually the width property returns the diameter of the circle. So, you can calculte the ray like this:

ray = diamter / 2
ray = circle.width / 2

Therefore if you get the distance between the 2 circles you can detect the collision like this:

if distance < ( circle1.width/2+ circle2.width/2 ) is true => Collision

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

// Start enter frame event
this.addEventListener(Event.ENTER_FRAME, enterFrame);
function enterFrame(pEvent:Event):void {
// Get distance between the 2 MovieClips
var dist:int = getDistance(myCircleBlu,myCircleRed);
// Test the distance and compare with the 2 rays
if (dist < myCircleRed.width/2 + myCircleBlu.width/2) {
// If collision is detected change the opacity
myCircleRed.alpha = 0.5;
myCircleBlu.alpha = 0.5;
} else {
myCircleRed.alpha = 1;
myCircleBlu.alpha = 1;
}
}
function getDistance(pObj1:MovieClip,pObj2:MovieClip):Number {
var distX:Number = pObj1.x - pObj2.x;
var distY:Number = pObj1.y - pObj2.y;
return Math.sqrt(distX * distX + distY * distY);
}

ActionScript: Get distance between 2 MovieClips

admin — Thu, 25 Nov 2010 15:09:10 +0000

If you want to get the distance in pixels between 2 graphic objects just use the Pythagorean theorem in ActionScript :).

c² = a² + b²

Download source : Get_Distance.zip

1
2
3
4
5

function getDistance(pObj1:MovieClip,pObj2:MovieClip):Number {
var distX:Number = pObj1.x - pObj2.x;
var distY:Number = pObj1.y - pObj2.y;
return Math.sqrt(distX * distX + distY * distY);
}