Benoit Freslon's blog - Game Design, Flash games, ActionScript tutorials ... » Tutorial

ActionScript: Tutorial How to create a gravity like a Mario platformer

admin — Wed, 02 Feb 2011 14:21:47 +0000

In this little tutorial you will learn how to create a gravity like a Mario platformer.

Let’s start!

Get files

Save these 2 sprites (Right click > Save as)

Open Flash and create a new ActionScript 3.0 document.
Document properties: 24 fps, 550×400 by default.

Create the Hero MovieClip

Create a new Symbol: Insert > New symbol > MovieClip
Symbol name: Hero
Check Export for ActionScript
And Click OK

Now you are in you Hero symbol! Perfect!
Import the first sprite: mario_stand.png on the first frame:
File > Import > Import to stage > mario_stand.png
Set the sprite just on the top of the little black cross (pivot point)
Now create an empty keyframe on the timeline:
Timeline > 2nd frame on the timeline > Right Click > Create empty Keyframe
Import the second sprite: mario_jump.jpg on the second keyframe
Then create a new layer on the top and set 2 labels names
Insert > Timeline > New layer
And add 2 labels names:
On the timeline click on the first key frame with the mario_stand.png sprite and go to the Properties pannel > Label > Name > stand
On the timeline click on the second key frame with the mario_jump.png sprite and go to the Properties pannel > Label > Name > jump

Add the jump script

Back to the main scene: Click on the Scene 1
Add a new layer named “Actions”: Insert > Timeline > New layer
And open the Actions pannel: Timeline > Actions Layer > Keyframe > Right click > Actions
Finally copy and paste this code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

// The game gravity
var gravity = 0.8;

// The floor position (y)
var floor = 300;

// Add the hero MovieClip
var hero = new Hero();
// Set the x position
hero.x = 550/2;
// Set the y position on the floor
hero.y = floor;
// Set the hero state to "stand"
hero.gotoAndStop("stand");

// Add hero on the display list
addChild(hero);

// Create and set the speedY property to 0
hero.speedY = 0
// Create and set the jump impulsion to 10
hero.impulsion = 10;
// Add an enter frame event
hero.addEventListener(Event.ENTER_FRAME, heroEnterFrame)
function heroEnterFrame (pEvent)
{
// On each frames...

// Set the world gravity
hero.speedY += gravity;

// Move the hero with his speedY
hero.y += hero.speedY;

// If the y property is larger than the floor position
if (hero.y > floor)
{
// Set the hero on the floor
hero.y = floor
// Cancel the current speed
hero.speedY = 0;
// Change the state to stand
hero.gotoAndStop("stand");
}
}

// Add a mouse event on the stage
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown)

function mouseDown (pEvent)
{
// When the user click on the stage...

// If the hero is standing
if (hero.currentLabel == "stand")
{
// Set the new speedY with the hero impulsion
hero.speedY = -hero.impulsion;
// And change the state to jump
hero.gotoAndStop("jump");
}
}

Download sources: www.benoitfreslon.com_Create_gravity_like_a_mario_plateformer

ActionScript: Move an object with keyboard with absolute controls

admin — Tue, 01 Feb 2011 11:29:30 +0000

In this tip I will show you how to move an object with keyboard with absolute controls.

What is the absolute controls?

The direction of your object will be calculated depending the object orientation. (Biohazard, Micro Machines, Gears of War). This code is very usefull if you design a car game.

How to make an absolute control in Flash?

Get the arrow key status (key is up/key is down);
Move or rotate the object on enter frame with the new velocity (Left and Right keys: rotate, Up key: forward, Down key: backward);

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90

// Assign 4 booleans for the 4 arrow keys
var keyUp = false;
var keyDown = false;
var keyLeft = false;
var keyRight = false;

// Add the keyboard event (KEY_DOWN) on the stage
stage.addEventListener(KeyboardEvent.KEY_DOWN, pressKey);
function pressKey(pEvent)
{
// If an arrow key is down, switch the value to true to the assigned variable
if (pEvent.keyCode == 38)
{
keyUp = true;
}
else if (pEvent.keyCode == 40)
{
keyDown = true;
}
else if (pEvent.keyCode == 37)
{
keyLeft = true;
}
else if (pEvent.keyCode == 39)
{
keyRight = true;
}
}
// Add the keyboard event (KEY_UP) on the stage
stage.addEventListener(KeyboardEvent.KEY_UP, releaseKey);
function releaseKey(pEvent)
{
// If the arrow key is up, switch the value to false to the assigned variable
if (pEvent.keyCode == 38)
{
keyUp = false;
}
else if (pEvent.keyCode == 40)
{
keyDown = false;
}
else if (pEvent.keyCode == 37)
{
keyLeft = false;
}
else if (pEvent.keyCode == 39)
{
keyRight = false;
}
}

// Set the velocity of the object
var speed = 6;
// And the rotation speed
var rotationSpeed = 5;

// Add an enter frame event on the moving object
myCircle.addEventListener(Event.ENTER_FRAME, circleEnterFrame);
function circleEnterFrame(pEvent)
{
// Set the default velocity to 0 if no key is pressed
var velocity = 0;
if (keyUp)
{
// If the key up is pressed set the new velocity to the speed value
velocity = speed;
}
if (keyDown)
{
// If the key down is pressed set the new velocity to the half speed value
velocity = -speed/2;
}
if (keyLeft)
{
// rotate the object
pEvent.currentTarget.rotation -= rotationSpeed;
}
if (keyRight)
{
// rotate the object
pEvent.currentTarget.rotation += rotationSpeed;
}

// Convert the degreeAngle to the radian angle
var angleRadian = pEvent.currentTarget.rotation / 180 * Math.PI;

// Move the object with the radian angle and the object speed
pEvent.currentTarget.x += Math.cos(angleRadian) * velocity;
pEvent.currentTarget.y += Math.sin(angleRadian) * velocity;
}

Download source: www.benoitfreslon.com_Move_an_object_with_keyboard_with_absolute_controls

ActionScript: Move an object with keyboard with camera relative control

admin — Tue, 04 Jan 2011 16:22:25 +0000

In this tip I will show you how to move an object with keyboard with camera relative control.

What is a camera relative control?

The direction of your object will be calculated depending the camera position. (Mario 64, Uncharted, GTA 3, etc.).
Eg: If press the right button the character will go on the right.

How to make a camera relative control?

Get the arrow key status (key is up/key is down)
Set the direction vector
Move the object on enter frame with the direction vector

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

// Assign 4 booleans for the 4 arrow keys
var keyUp = false;
var keyDown = false;
var keyLeft = false;
var keyRight = false;

// Add the keyboard event (KEY_DOWN) on the stage
stage.addEventListener(KeyboardEvent.KEY_DOWN, pressKey);
function pressKey(pEvent) {
// If an arrow key is down, switch the value to true to the assigned variable
if (pEvent.keyCode == 38) {
keyUp = true;
} else if (pEvent.keyCode == 40) {
keyDown = true;
} else if (pEvent.keyCode == 37) {
keyLeft = true;
} else if (pEvent.keyCode == 39) {
keyRight = true;
}
}
// Add the keyboard event (KEY_UP) on the stage
stage.addEventListener(KeyboardEvent.KEY_UP, releaseKey);
function releaseKey(pEvent) {
// If the arrow key is up, switch the value to false to the assigned variable
if (pEvent.keyCode == 38) {
keyUp = false;
} else if (pEvent.keyCode == 40) {
keyDown = false;
} else if (pEvent.keyCode == 37) {
keyLeft = false;
} else if (pEvent.keyCode == 39) {
keyRight = false;
}
}

// Set the velocity of the object
var speed = 6;

// Add an enter frame event on the moving object
myCircle.addEventListener(Event.ENTER_FRAME, circleEnterFrame);
function circleEnterFrame(pEvent) {
// Create a 2D vector in order to get the object direction according the arrow keys
var vector = new Point(0,0);
if (keyUp) {
// If keyUp is true add the -1 value on the y axis
vector.y += -1;
}
if (keyDown) {
// If keyDown is true add the 1 value on the y axis
vector.y += 1;
}
if (keyLeft) {
// If keyLeft is true add the -1 value on the x axis
vector.x += -1;
}
if (keyRight) {
// If keyRight is true add the 1 value on the x axis
vector.x += 1;
}

// Get the radian angle of the direction
var angle = Math.atan2(vector.y,vector.x);

// If vector lenght is not null
if (vector.length > 0) {
// Move the object with the angle and the object speed
pEvent.currentTarget.x += Math.cos(angle) * speed;
pEvent.currentTarget.y += Math.sin(angle) * speed;
}
}

[kml_flashembed publishmethod="static" fversion="10.0.0" movie="http://www.benoitfreslon.com/wp-content/uploads/2011/01/www.benoitfreslon.com-Move-an-objet-with-keyboard-with-camera-relative-control.swf" width="550" height="400" targetclass="flashmovie"]

Donwload source: www.benoitfreslon.com-Move-an-objet-with-keyboard-with-camera-relative-control.zip

ActionScript: Move an object to coordinates with smoothing

admin — Mon, 03 Jan 2011 15:53:50 +0000

There is a simple formula to move an object to coordinates with smoothing.
The speed will decrease with smooth during the time.

speed = distance_between_objects / smoothing

The distance will decrease because the distance will decrease too.

If I set values I got:

object.x = 50
targetX = 100

speedX = (targetX – object.x) / 5

On the first frame: speed = 10
object.x += (100 – 50) /5 > 50/5 > 10
> object.x = 50+10 = 60

On the second frame: speed = 8
object.x += (100 – 60) /5 > 40/5 = 8
> object.x = 60 + 8 = 68

On the third frame: speed = 6,4
object.x += (100 – 68) / 5 > 32/5 = 6,4
> object.x = 68 + 6,4 = 74,4

etc.

On the 100th frame: speed = 0
object.x += (100 – 100) / 5 > 0 /5 = 0
> object.x = 100 + 0 = 100

Source:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

// Add a mouse event on the stage
stage.addEventListener(MouseEvent.CLICK, click);
function click(pEvent) {
// On click set the new x and y coordinates
myBall.targetX = stage.mouseX;
myBall.targetY = stage.mouseY;
}

// Set default coordinates
myBall.targetX = 200;
myBall.targetY = 200;

// Add an enter frame event on the ball
myBall.addEventListener(Event.ENTER_FRAME, ballEnterFrame);
function ballEnterFrame(pEvent) {
// On enter frame move the ball to the target coordinates
var b = pEvent.currentTarget;
b.x += (b.targetX - b.x) / 8;
b.y += (b.targetY - b.y) / 8;
}

Exemple:

Download source: www.benoitfreslon.com Move an object to coordinates with smoothing.zip

ActionScript: Throw bullets to mouse direction

admin — Mon, 27 Dec 2010 12:50:13 +0000

After calculating the angle of 2 graphic objects, you can also use this angle to throw a bullet to the object direction with the trigonometry.

How ?

Calculating the angle (in radian) between 2 graphics objects with the Math.atan2 method (cf. Orient object to the mouse cursor).
On click, display a bullet to the “tank” position and add an “enter frame” event on this bullet.
And save the angle between the tank and the mouse cursor on the new bullet.
Use this angle on the “enter frame” event to calculate the x and y speed with the cosinus and the sinus.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

import flash.display.MovieClip;
import flash.geom.Point;
import flash.events.MouseEvent;

// Code by Benoit Freslon.
// Tutorials, Flash games:
// http://www.benoitfreslon.com

// This object will always look at the mouse cursor
myTank.addEventListener(Event.ENTER_FRAME, tankEnterFrame);
// This function will be launched every frame (25 times by seconds);
function tankEnterFrame(pEvt) {
// pEvt.currentTarget: myTank
var mc = pEvt.currentTarget;
// Get the radian angle between the tank and the cursor
// You can also replace mouseX and mouseY by another coordinates
var angleRadian = Math.atan2(mouseY - mc.y,mouseX - mc.x);
// Convert the radian angle in dedree angle
var angleDegree = angleRadian * 180 / Math.PI;
// Set the orientation
mc.rotation = angleDegree;
// Display angle of rotation in degree
txtAngle.text = Math.round(angleDegree) + "°";
}

// Add a mouse down event on stage
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);

function mouseDown(pEvent) {
// Create a new bullet
var b = new Bullet();
// Set his position to the tank position
b.x = myTank.x;
b.y = myTank.y;
// Save the randian angle between the mouse and the tank
// This angle will set the direction of the bullet
b.angleRadian = Math.atan2(mouseY - myTank.y,mouseX -myTank.x);
// Add an enter frame event on each bullet
b.addEventListener(Event.ENTER_FRAME, bulletEnterFrame);
// Add this display object on the display list
addChild(b);
}

// Velocity of each bullet
var speed = 8;

function bulletEnterFrame(pEvent) {
// Get the current object (Bullet)
var b = pEvent.currentTarget;
// Move this bullet on each frames
// On X axis use the cosinus angle
b.x += Math.cos(b.angleRadian) * speed;
// On Y axis use the sinus angle
b.y += Math.sin(b.angleRadian) * speed;
// Orient the bullet to the direction
b.rotation = b.angleRadian * 180 / Math.PI;
// You have to remove each created bullet
// So after every moves you must check bullet position
// If the bullet is out of the screen
if (b.x < 0 || b.x > 400 || b.y < 0 || b.y > 400) {
// Remove it from the display list
removeChild(b);
// /!\ AND REOMOVE HIS EVENT LISTER
b.removeEventListener(Event.ENTER_FRAME, bulletEnterFrame);
}
}

Download source: www.benoitfreslon.com_Throw_bullets_to_mouse_direction.zip

ActionScript: Detect collision between 2 circles

admin — Fri, 03 Dec 2010 11:02:25 +0000

With the Pythagoeran theorem you can detect collision with 2 circles.

You just have to get the rays of 2 circles with the width property divided by 2.
Actually the width property returns the diameter of the circle. So, you can calculte the ray like this:

ray = diamter / 2
ray = circle.width / 2

Therefore if you get the distance between the 2 circles you can detect the collision like this:

if distance < ( circle1.width/2+ circle2.width/2 ) is true => Collision

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

// Start enter frame event
this.addEventListener(Event.ENTER_FRAME, enterFrame);
function enterFrame(pEvent:Event):void {
// Get distance between the 2 MovieClips
var dist:int = getDistance(myCircleBlu,myCircleRed);
// Test the distance and compare with the 2 rays
if (dist < myCircleRed.width/2 + myCircleBlu.width/2) {
// If collision is detected change the opacity
myCircleRed.alpha = 0.5;
myCircleBlu.alpha = 0.5;
} else {
myCircleRed.alpha = 1;
myCircleBlu.alpha = 1;
}
}
function getDistance(pObj1:MovieClip,pObj2:MovieClip):Number {
var distX:Number = pObj1.x - pObj2.x;
var distY:Number = pObj1.y - pObj2.y;
return Math.sqrt(distX * distX + distY * distY);
}

ActionScript: Get distance between 2 MovieClips

admin — Thu, 25 Nov 2010 15:09:10 +0000

If you want to get the distance in pixels between 2 graphic objects just use the Pythagorean theorem in ActionScript :).

c² = a² + b²

Download source : Get_Distance.zip

1
2
3
4
5

function getDistance(pObj1:MovieClip,pObj2:MovieClip):Number {
var distX:Number = pObj1.x - pObj2.x;
var distY:Number = pObj1.y - pObj2.y;
return Math.sqrt(distX * distX + distY * distY);
}

ActionScript: Orient an object to the mouse cursor

admin — Sat, 09 Jan 2010 18:17:14 +0000

How to orient an objet to an other ? Just put those lines and change the instance name myTank.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16

// This object will always look at the mouse cursor
myTank.addEventListener(Event.ENTER_FRAME, tankEnterFrame);
// This function will be launched every frame (25 times by seconds);
function tankEnterFrame(pEvt) {
// pEvt.currentTarget : myTank
var mc = pEvt.currentTarget;
// Get the radian angle between the tank and the cursor
// You can also replace mouseX and mouseY by another coordinates
var angleRadian=Math.atan2(mouseY-mc.y,mouseX-mc.x);
// Convert the radian angle in dedree
var angleDegree = angleRadian * 180 / Math.PI;
// Set the orientation
mc.rotation = angleDegree;
// Display angle of rotation in degree
txtAngle.text = Math.round(angleDegree) + "°";
}

Download the source code here : [www.thisisgameplay.com]_Orient_object_to_mouse_cursor.fla

Tutorial: How to make a game like Jetman – step 1 – The Jetman

admin — Fri, 18 Dec 2009 17:06:36 +0000

In my first tutorial I will show you how to make a flash game like Jetman.
A simple very famous casual game on facebook and very addictive.

Play Jetman

1. First of all you have to download the Adobe Flash IDE: Adobe Flash CS3 or Adobe Flash CS4

We will code the game with ActionScript 3.0 (the programming language of Flash) so you need Adobe Flash CS3 at least.
You can download the free trial version of Adobe Flash here (Mac or Windows) : https://www.adobe.com/cfusion/tdrc/index.cfm?loc=en&product=flash

2. Create your document

Open Flash.
Create a new ActionScript 3.0 document.
On the properties set the framerate to 25fps.
And set the background color to black.

3. Create Jetman MovieClip

Flash uses graphic objects called MovieClip. So we have to create the Jetman’s MovieClip.

Click on the Rectangle tool on the tools bar. (on the left)

Then drag and drop on the stage to create a rectangle about width:50px and height:15px (you can modify your shape dimentions later).
Select all your shape including the border. You can also use a double click.
Do a right click on your selected shape and click on Convert to Symbol.
Write this symbol’s name : Jetman (not jetman or JETMAN).
Then click OK.

Now you can see your Symbol Jetman into your Library (on the right). If you don’t see the Library Press F11 key.
You have 1 instance of the Jetman symbol on your stage. Good. We just created a MovieClip.

In order to interact with the jetman MovieClip with ActionScript, we have the rename the instance’s name on the stage.

Click on the Jetman’s instance on the stage.

Then go to the properties on the bottom and set the instance’s name to jetman (not Jetman or JETMAN) it’s very important.

It’s done! Now we can move the instance with ActionScript.

4. Starting to code

You have differents ways to code with ActionScript. We will use the easier. (Coding into layers)

Create a new layer on the timeline (Click on the button on the left bottom corner).
Put the layer on the top: drag and drop the layer.
You can rename the layer with a double click or Right Click then rename.
Then select the first frame (here in black).

Finally go to the windows menu > Actions or press the F9 key.

A new windows is opening : The Actions window. We will to write all our code here.

Copy and paste this Actionscript 3 code (After codinf into your layer you should see a little a into this frame):

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

// Please don't remove this comment.
// Code by Benoit Freslon.
// Tutorials, Flash games:
// http://www.thisisgameplay.com
//

////// Game balance
// Jetpack's boost speed
var speedBoost = -4;
// Gravity
var gravity = .8;
// Speed limit
var speedMax = 5;

////// Global variables don't touch those one
// Jetman is using his jetpack ?
var boost = false;
// Jetman's current speed
var speed = 0;

// 25 times by seconds this function will be launched
function jetmanEnterFrame(pEvt) {
// If boost == true
if (boost) {
// The speed changes
speed = speedBoost;
} else {
// Else the gravity decrease jetman's speed
speed += gravity;
}
// If the current speed is to hi
if (speed > speedMax) {
// Limit the speed
speed = speedMax;

// If the current speed is to low
} else if (speed < -speedMax) {
// Limit the speed
speed = - speedMax;
}
// Every frame jetman will move vertically. (y axis)
jetman.y += speed;

// If jetman is out of the screen
if (jetman.y > 450) {
jetman.y = 100;
}
}
// Add a event listener to launch the jetmanEnterFrame function every frames
jetman.addEventListener(Event.ENTER_FRAME, jetmanEnterFrame);

// If the mouse is pressed
function mouseDown(pEvt) {
// Set boost to true
boost = true;
}
// Id the mouse is released
function mouseUp(pEvt) {
// Set boost to false
boost = false;
}
// Detecting the mouse inputs (MOUSE_DOWN and MOUSE_UP) on the entire "stage"
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown);
stage.addEventListener(MouseEvent.MOUSE_UP, mouseUp);

Finally test your game. (hit CTRL+ENTER)

You should see that:

Download the source file here:

[www.thisisgameplay.com]_Jetman_step1.fla

Download the compiled file here:

[www.thisisgameplay.com]_Jetman_step1.swf

Next step the level design… ;)

http://photos-g.ak.fbcdn.net/photos-ak-sf2p/v43/106/4243149646/app_1_4243149646_252.gif